用vbs实现本地连接禁用/启用脚本代码

转载至 http://community.csdn.net/Expert/topic/4881/4881882.xml

Const ssfCONTROLS = 3  

sConnectionName = "本地连接"  '可改成需要控制的连接名称，如"无线网络连接"等  

sEnableVerb = "启用(&A)"  
sDisableVerb = "禁用(&B)"   'XP系统中应为 "停用(&B)"  

set shellApp = createobject("shell.application")  
set oControlPanel = shellApp.Namespace(ssfCONTROLS)  

set oNetConnections = nothing  
for each folderitem in oControlPanel.items  
 if folderitem.name  = "网络连接" then  
   set oNetConnections = folderitem.getfolder: exit for  
 end if  
next  

if oNetConnections is nothing then  
 msgbox "未找到网络连接文件夹"  
 wscript.quit  
end if  

set oLanConnection = nothing  
for each folderitem in oNetConnections.items  
 if lcase(folderitem.name)  = lcase(sConnectionName) then  
   set oLanConnection = folderitem: exit for  
 end if  
next  

if oLanConnection is nothing then  
 msgbox "未找到 '" & sConnectionName & "' item"  
 wscript.quit  
end if  

bEnabled = true  
set oEnableVerb = nothing  
set oDisableVerb = nothing  
s = "Verbs: " & vbcrlf  
for each verb in oLanConnection.verbs  
 s = s & vbcrlf & verb.name  
 if verb.name = sEnableVerb then   
   set oEnableVerb = verb    
   bEnabled = false  
 end if  
 if verb.name = sDisableVerb then   
   set oDisableVerb = verb    
 end if  
next  

'debugging displays left just in case...  
'  
'msgbox s ': wscript.quit  
'msgbox "Enabled: " & bEnabled ': wscript.quit  

'not sure why, but invokeverb always seemed to work   
'for enable but not disable.    
'  
'saving a reference to the appropriate verb object   
'and calling the DoIt method always seems to work.  
'  
if bEnabled then  
'  oLanConnection.invokeverb sDisableVerb  
 oDisableVerb.DoIt  
else  
'  oLanConnection.invokeverb sEnableVerb  
 oEnableVerb.DoIt  
end if  

'adjust the sleep duration below as needed...  
'  
'if you let the oLanConnection go out of scope  
'and be destroyed too soon, the action of the verb  
'may not take...  
'  
wscript.sleep 400 

右键发送(sendto)，创建快捷方式到自定义的位置
在SendTo文件夹里加上一文件夹的快捷方式后，在右键发送到这个文件夹的是这些文件的一个副本，实际上是一个复制的过程，有时候我们只希望是快捷

[导入][原创]用脚本控制迅雷下载
一个网上的朋友想用脚本调用迅雷下载，于是我研究了一下，觉得可以，弄出来跟大家分享首先呢，找到迅雷在IE右健添加的东东：用迅雷下载链接。于

vbs中关于计算机名的相关讨论
原文：http://www.opencjk.org/~scz/关于计算机名的相关讨论http://www.opencjk.org/~scz/windows/200603151441.txtQ:我的电脑-属性-计算机名-计算机描述，我想改动这里，但